LoRaWAN ABP

Este exemplo apresenta a transmissão LoRaWAN ABP com o módulo IoT JVTECH. Lembrando de ligar a alimentação do rádio LoRa.

Dependência

-> Lmic

A biblioteca pode ser baixada dentro da própria Arduino IDE, através do gerenciador de bibliotecas.

Exemplo

/*
Autor: João Vitor Alvares
Versão: 1.0
Objetivo: Tranmissão LoRaWAN ABP com o MIJ (Módulo IoT JVTECH)
Ligar a chave da placa para alimentar o LoRa
*/

#include <lmic.h> // Biblioteca MCCI LoRaWAN LMIC library versão: 2.3.2 por Terry Moore
#include <hal/hal.h> // Biblioteca nativa do ESP32
#include <SPI.h> // Biblioteca nativa do ESP32
// Para ESP32
#include <Arduino.h> // Biblioteca nativa do ESP32

// Credenciais
// CHIRPSTACK - CS (8 at 15 + 65 canais):
// big-endian 
static const u1_t PROGMEM APPSKEY[16] = {0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
// big-endian 
static const PROGMEM u1_t NWKSKEY[16] = {0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
// big-endian
static const u4_t DEVADDR = 0x00000000; 

// Protótipo das funções
void os_getArtEui(u1_t *buf) {}
void os_getDevEui(u1_t *buf) {}
void os_getDevKey(u1_t *buf) {}

// Dados para enviar
static uint8_t mydata[] = "jvtech-teste01";

// Instância
static osjob_t sendjob;

// Tempo de envio em milisegundos
const unsigned TX_INTERVAL = 10;

// Pinos
const lmic_pinmap lmic_pins = {

    .nss = 5,
    .rxtx = LMIC_UNUSED_PIN,
    .rst = 14,
    .dio = {26, 13, LMIC_UNUSED_PIN}, // (DIO0, DIO1)

};

// Funções de evento LoRaWAN
void onEvent (ev_t ev) {

    switch(ev) {
        case EV_SCAN_TIMEOUT:
            Serial.println(F("EV_SCAN_TIMEOUT"));
            break;
        case EV_BEACON_FOUND:
            Serial.println(F("EV_BEACON_FOUND"));
            break;
        case EV_BEACON_MISSED:
            Serial.println(F("EV_BEACON_MISSED"));
            break;
        case EV_BEACON_TRACKED:
            Serial.println(F("EV_BEACON_TRACKED"));
            break;
        case EV_JOINING:
            Serial.println(F("EV_JOINING"));
            break;
        case EV_JOINED:
            Serial.println(F("EV_JOINED"));
            break;
        case EV_JOIN_FAILED:
            Serial.println(F("EV_JOIN_FAILED"));
            break;
        case EV_REJOIN_FAILED:
            Serial.println(F("EV_REJOIN_FAILED"));
            break;
        case EV_TXCOMPLETE:
            Serial.println(F("EV_TXCOMPLETE (includes waiting for RX windows)"));
            if (LMIC.txrxFlags & TXRX_ACK)
              Serial.println(F("Received ack;"));
            if (LMIC.dataLen) {
              Serial.print(F("Received "));
              Serial.print(LMIC.dataLen);
              Serial.println(F(" byte(s) of payload."));
            }
            os_setTimedCallback(&sendjob, os_getTime()+sec2osticks(TX_INTERVAL), do_send); // Configuração da próxima transmissão
            break;
        case EV_LOST_TSYNC:
            Serial.println(F("EV_LOST_TSYNC"));
            break;
        case EV_RESET:
            Serial.println(F("EV_RESET"));
            break;
        case EV_RXCOMPLETE:          
            Serial.println(F("EV_RXCOMPLETE")); // Dados recebidos
            break;
        case EV_LINK_DEAD:
            Serial.println(F("EV_LINK_DEAD"));
            break;
        case EV_LINK_ALIVE:
            Serial.println(F("EV_LINK_ALIVE"));
            break;
        case EV_TXSTART:
            Serial.println(F("EV_TXSTART"));
            break;
        default:
            Serial.print(F("Unknown event: "));
            Serial.println((unsigned) ev);
            break;
    }

}

void do_send(osjob_t* j){

    if (LMIC.opmode & OP_TXRXPEND) { // Verifica se tem algum processo TX e RX ocorrendo
  
        Serial.println(F("OP_TXRXPEND, not sending"));
    
    } else { // Prepara os dados para envio na próxima janela

        LMIC_setTxData2(1, mydata, sizeof(mydata)-1, 0);
        Serial.println(F("Packet queued"));
    
    }

}

void setup() {
  
    Serial.begin(115200); // Iniciar serial
    delay(100);
    Serial.println(F("Starting..."));
  
  // SPI.begin(18, 19, 23, 5); // Iniciar SPI - (SCK,MISO,MOSI,SS)

    os_init(); // Inicia biblioteca LoRaWAN
    
    LMIC_reset(); // Reinicia rádio LoRa

    uint8_t appskey[sizeof(APPSKEY)];
    uint8_t nwkskey[sizeof(NWKSKEY)];
    memcpy_P(appskey, APPSKEY, sizeof(APPSKEY));
    memcpy_P(nwkskey, NWKSKEY, sizeof(NWKSKEY));
    LMIC_setSession (0x13, DEVADDR, nwkskey, appskey); // Configura LoRaWAN

    // Controle dos canais para AU915 (8 at 15 + 65 canais)
    for (u1_t b = 0; b < 8; ++b){
    
        LMIC_disableSubBand(b);
    }

    for (u1_t channel = 0; channel < 72; ++channel){
    
        LMIC_disableChannel(channel);
    }

    LMIC_enableChannel(8); // Habilita o canal
    // LMIC_enableChannel(9);
    // LMIC_enableChannel(10);
    // LMIC_enableChannel(11);
    // LMIC_enableChannel(12);
    // LMIC_enableChannel(13);
    // LMIC_enableChannel(14);
    // LMIC_enableChannel(15);
  // LMIC_enableChannel(65);

    LMIC_setAdrMode(0); // Desabilita o ADR
    
    LMIC_setLinkCheckMode(0); // Desabilita a verificação de validação

    LMIC.dn2Dr = DR_SF9; // Configra Spreading Factor para a janela de recepção (Usado para TTN)

    LMIC_setDrTxpow(DR_SF7,14); // Configura o Spreading Factor e potência

    LMIC_setClockError (MAX_CLOCK_ERROR * 10 / 100); // Configura o clock

    do_send(&sendjob); // Inicia os trabalhos

}

void loop() {

    os_runloop_once(); // Loop de envio

}